(03-13-2013, 11:49 PM)Fat Tony link Wrote: If you have a example file and willing to provide it here, it will maybe sort it out aswell!Here's a snippet from a mission I made:
Code:
private ["_currentMissionSettings", "_count", "_i"];
_currentMissionSettings = "";
_count = count (missionConfigFile >> "Params");
for [ {_i = 0}, {_i < _count }, {_i = _i + 1} ] do
{
  private ["_pname", "_title", "_text"];
  _pname = configName ((missionConfigFile >> "Params") select _i);
  _title = missionNamespace getVariable [format["%1_Title", _pname], ""];
  _text = missionNamespace getVariable [format["%1_Value", _pname], ""];
 Â
  _currentMissionSettings = _currentMissionSettings + format["%1: %2", _title, _text] + "<br/>";
};
[
FHQ_playerGroup,
["Mission", "US Ranger team 'Raven' is sent to a <marker name=""markJazar"">nearby village</marker> to investigate potential insurgent activity"],
["Background",
    "The 75th Ranger Batallion is currently setting up shop at the <marker name=""markAirfield"">South Airfield</marker> " +
    "in response to the start of Operation Righteous Cause. We're here as part of an international peacekeeping force " +
    "in northern Takistan under United Nations Security Council Resolution #2423.<br/><br/>" +
    "British, Czech and German forces are expected to arrive tomorrow or the day after at latest. until that time, " +
    "we're on our own.<br/><br/>" +
  "Reshmaan Province is one of the nothernmost provinces of Takistan. <marker name=""labelArdistan"">Ardistan</marker> lies directly to "+
    "the west. About 100 kilometer further north is the border of Russia. It goes without saying that " +
    "you are to respect these borders at all costs, anything else might cause an international incident " +
    "and might give Ardistan a reason to throw their weight into the insurgency publically."
    ],
    ["Situation",
     "Fifteen minutes ago we have received a cell phone call from a nearby village. The call was in " +
     "broken English, and apparently tried to explain that the village is or was terrorized by a " +
     "group of insurgents.<br/><br/>" +
     "The village of <marker name=""markJazar"">Ghufran</marker> " +
     "is rather insignificant, but this is our first chance to convince the locals that we're on their side. " +
     "Your team is sent out to investigate, and, if necessary, intervene. <br/><br/>" +
     "Be advised, though, that the area outside the airfield should be considered hostile. Security is low, we have a " +
     "couple of patrols in the area but nothing solid"
    ],
["Execution",
    "We have an SOV on standby to take you to the village. Ghufran is located about 1.5 klicks " +
      "to the north west of the airfield, along the road leading north. Investigate the " +
      "situation, and report back to HQ.<br/><br/>" +
      "Your team will be fielding the new ACR (designated Mk 22 Mod 0) during this operation. The " +
      "ACR uses a 6.8 SPC round, so its lethality should be better than that of the M4 or Mk16. " +
      "Please file regular reports about the performance of the weapon."
    ],
    ["Opposing forces",
    "The local insurgents know these hills very well. Chances of ambushes along the road are " +
      "high. For the time being, however, a clear picture of the local insurgent forces is not available. " +
      "Be on your guard."
    ],
["Allied forces",
    "Occasional foot patrols are operating in the area, however, they are ordered " +
    "to stay <marker name=""labelPatrol"">within half a klick</marker> of the airbase. "
    ]
] call FHQ_TT_addBriefing;
[
FHQ_playerGroup,
  ["taskInvestigate", // Task name
    "Investigate Ghulfran. A villager has notified command of potential insurgent activity. Drive to the village and investigate.", // Task text in briefing
    "Investigate", // Task title in briefing
    "Investigate", // Waypoint text
    getMarkerPos "markJazar", // position of task, or object task is tied to
    "assigned" // Optional: Initial state
    ]
] call FHQ_TT_addTasks;
I think you problem is
[quote]["Mission", "Drink some tea"] >>,<<
]
call FHQ_TT_addBriefing;[/qiote]
that comma over there.
EDIT: LOL I just saw it was Varanon's fault
I don't need luck, I have ammo.