12-03-2014, 10:00 PM
What kind of trigger is it? Here's the thing: thisList contains only the units satisfy the activation field. So, setting the trigger activation to "Anyone" will always return as thisList (or list triggerName) all units that are in the trigger.
Of course, there is another issue. Only the driver of a vehicle is listed. If you have a truck full of people, only the driver will appear in thisList. I use this script for that purpose
FHQ_UnitsInTrigger = {
  /*
  * Returns an array of units that are in a trigger, counting vehicle cargo
  *
  * _this select 0: (Object) Trigger name
  * _this select 1: (Boolean Optional) if true, filter for playable units
  */
  private ["_res", "_trigger", "_filter"];
 Â
  _trigger = [_this, 0, objNull, [objNull]] call BIS_fnc_param;
  _filter = [_this, 1, false, [false]] call BIS_fnc_param;
 Â
  _res = [];
  {
    if (!(_x isKindOf "Man")) then {
      private "_veh";
      _veh = vehicle _x;
      { _res set [count _res, _x]; } forEach crew _veh;
    } else {
      _res set [count _res, _x];
    };
  } forEach list _trigger;
 Â
  if (_filter) then {
    {
      if (!(_x in playableUnits)) then {
        _res set [_forEachIndex, objNull];
      };
    } forEach _res;
    _res = _res - [objNull];   Â
  };
 Â
  _res
};
This will go through all units in thisList and check if they are the driver of a vehicle, and if so, add the complete crew and cargo to the list. If the second parameter is true, it removes all non-player units afterwards.
Be aware that this requires a named trigger, and should be called only periodically, or under certain conditions. I usually have an FSM controlling mission flow, and make sure to count these only when the rest of the mission's goals are finished.
I don't need luck, I have ammo.